@echo off
chcp 65001 >nul
title DEVSYS · Servidor de Rede

:: Verifica se está rodando como administrador
net session >nul 2>&1
if %errorlevel% neq 0 (
    echo  Solicitando permissao de administrador...
    powershell -Command "Start-Process '%~f0' -Verb RunAs"
    exit /b
)

cd /d "%~dp0"

:: Abre regra de firewall para porta 7180
netsh advfirewall firewall delete rule name="DEVSYS 7180" >nul 2>&1
netsh advfirewall firewall add rule name="DEVSYS 7180" dir=in action=allow protocol=TCP localport=7180 >nul
echo  [OK] Firewall liberado para porta 7180

echo.
echo  Atualizando dados do banco...
python gerar_acesso.py
if errorlevel 1 (
    echo  ERRO ao atualizar dados. Verifique o banco de dados.
    pause
    exit /b
)

echo.
echo ====================================================
echo   DEVSYS · Vendas - Servidor de Rede ativo
echo ====================================================
echo   Local  : http://localhost:7180/acesso_vendedor.html
echo   Rede   : http://192.168.0.115:7180/acesso_vendedor.html
echo ====================================================
echo.

start "" "http://localhost:7180/acesso_vendedor.html"

python servidor.py
pause